setboundarycondition_DGModel3D Subroutine

  subroutine setboundarycondition_DGModel3D(this)
    !! Boundary conditions for the solution are set to
    !! 0 for the external state to provide radiation type
    !! boundary conditions.
    implicit none
    class(DGModel3D),intent(inout) :: this
    ! local
    integer :: i,iEl,j,k,e2,bcid
    real(prec) :: nhat(1:3),x(1:3)

    call gpuCheck(hipMemcpy(c_loc(this%solution%boundary), &
                            this%solution%boundary_gpu,sizeof(this%solution%boundary), &
                            hipMemcpyDeviceToHost))

    call gpuCheck(hipMemcpy(c_loc(this%solution%extboundary), &
                            this%solution%extboundary_gpu,sizeof(this%solution%extboundary), &
                            hipMemcpyDeviceToHost))

    do concurrent(k=1:6,iel=1:this%mesh%nElem)

      bcid = this%mesh%sideInfo(5,k,iEl) ! Boundary Condition ID
      e2 = this%mesh%sideInfo(3,k,iEl) ! Neighboring Element ID

      if(e2 == 0) then
        if(bcid == SELF_BC_PRESCRIBED) then

          do j = 1,this%solution%interp%N+1 ! Loop over quadrature points
            do i = 1,this%solution%interp%N+1 ! Loop over quadrature points
              x = this%geometry%x%boundary(i,j,k,iEl,1,1:3)

              this%solution%extBoundary(i,j,k,iEl,1:this%nvar) = &
                this%hbc3d_Prescribed(x,this%t)
            enddo
          enddo

        elseif(bcid == SELF_BC_RADIATION) then

          do j = 1,this%solution%interp%N+1 ! Loop over quadrature points
            do i = 1,this%solution%interp%N+1 ! Loop over quadrature points
              nhat = this%geometry%nhat%boundary(i,j,k,iEl,1,1:3)

              this%solution%extBoundary(i,j,k,iEl,1:this%nvar) = &
                this%hbc3d_Radiation(this%solution%boundary(i,j,k,iEl,1:this%nvar),nhat)
            enddo
          enddo

        elseif(bcid == SELF_BC_NONORMALFLOW) then

          do j = 1,this%solution%interp%N+1 ! Loop over quadrature points
            do i = 1,this%solution%interp%N+1 ! Loop over quadrature points
              nhat = this%geometry%nhat%boundary(i,j,k,iEl,1,1:3)

              this%solution%extBoundary(i,j,k,iEl,1:this%nvar) = &
                this%hbc3d_NoNormalFlow(this%solution%boundary(i,j,k,iEl,1:this%nvar),nhat)
            enddo
          enddo

        endif
      endif

    enddo

    call gpuCheck(hipMemcpy(this%solution%extBoundary_gpu, &
                            c_loc(this%solution%extBoundary), &
                            sizeof(this%solution%extBoundary), &
                            hipMemcpyHostToDevice))

  endsubroutine setboundarycondition_DGModel3D