WriteTecplot_MultiSetModel3D_t Subroutine

  subroutine WriteTecplot_MultiSetModel3D_t(this,filename)
    !! Write one rank-local Tecplot file per set with elements on this rank.
    !!
    !! Without filename, set k writes set<k>.solution.<rank>.<ioIterate>.tec. With
    !! filename, set k writes set<k>.<filename>. Rank-local; no collectives.
    implicit none
    class(MultiSetModel3D_t),intent(inout) :: this
    character(*),intent(in),optional :: filename
    ! Local
    integer :: k
    character(5) :: rankString
    character(13) :: timeStampString
    character(4) :: setString
    character(LEN=self_FileNameLength) :: tecFile

    write(rankString,'(I5.5)') this%globalMesh%decomp%rankId
    write(timeStampString,'(I13.13)') this%ioIterate
    do k = 1,this%nSets
      if(this%sets(k)%mesh%nElem == 0) cycle
      write(setString,'(I4.4)') k
      if(present(filename)) then
        tecFile = 'set'//setString//'.'//trim(filename)
      else
        tecFile = 'set'//setString//'.solution.'//rankString//'.'//timeStampString//'.tec'
      endif
      call this%sets(k)%model%WriteTecplot(trim(tecFile))
    enddo

  endsubroutine WriteTecplot_MultiSetModel3D_t