MPIAnisoMortarExchangeAsync_MappedScalar3D_t Subroutine

  subroutine MPIAnisoMortarExchangeAsync_MappedScalar3D_t(this,mesh)
    !! Posts the point-to-point messages required for anisotropic mortar interfaces
    !! whose big and small elements reside on different ranks; the two-half analogue of
    !! MPIMortarExchangeAsync, with tags built from the small faces' global side ids.
    implicit none
    class(MappedScalar3D_t),intent(inout) :: this
    type(Mesh3D),intent(inout) :: mesh
    ! Local
    integer :: m,h,ivar
    integer :: eB,sB,rB,eS,sS,rS
    integer :: globalSideId,tag
    integer :: offset
    integer :: iError
    integer :: msgCount

    ! A send and a receive per rank-crossing half, per variable.
    call mesh%decomp%ReserveMessages(2*this%nvar* &
                                     mesh%decomp%CountRemoteMortarSides(mesh%anisoMortarInfo,mesh%nAnisoMortars,2))

    msgCount = 0
    offset = mesh%decomp%offsetElem(mesh%decomp%rankId+1)

    do ivar = 1,this%nvar
      do m = 1,mesh%nAnisoMortars

        eB = mesh%anisoMortarInfo(1,m)
        sB = mesh%anisoMortarInfo(2,m)
        rB = mesh%decomp%elemToRank(eB)

        do h = 1,2

          eS = mesh%anisoMortarInfo(2*h+1,m)
          sS = mesh%anisoMortarInfo(2*h+2,m)/10
          rS = mesh%decomp%elemToRank(eS)
          globalSideId = mesh%anisoMortarInfo(6+h,m)
          tag = globalSideId+mesh%nUniqueSides*(ivar-1)

          if(rB == mesh%decomp%rankId .and. rS /= mesh%decomp%rankId) then

            msgCount = msgCount+1
            call MPI_IRECV(this%anisoMortarBuff(:,:,2+h,m,ivar), &
                           (this%interp%N+1)*(this%interp%N+1), &
                           mesh%decomp%mpiPrec, &
                           rS,tag, &
                           mesh%decomp%mpiComm, &
                           mesh%decomp%requests(msgCount),iError)

            msgCount = msgCount+1
            call MPI_ISEND(this%boundary(:,:,sB,eB-offset,ivar), &
                           (this%interp%N+1)*(this%interp%N+1), &
                           mesh%decomp%mpiPrec, &
                           rS,tag, &
                           mesh%decomp%mpiComm, &
                           mesh%decomp%requests(msgCount),iError)

          elseif(rS == mesh%decomp%rankId .and. rB /= mesh%decomp%rankId) then

            msgCount = msgCount+1
            call MPI_IRECV(this%anisoMortarBuff(:,:,h,m,ivar), &
                           (this%interp%N+1)*(this%interp%N+1), &
                           mesh%decomp%mpiPrec, &
                           rB,tag, &
                           mesh%decomp%mpiComm, &
                           mesh%decomp%requests(msgCount),iError)

            msgCount = msgCount+1
            call MPI_ISEND(this%boundary(:,:,sS,eS-offset,ivar), &
                           (this%interp%N+1)*(this%interp%N+1), &
                           mesh%decomp%mpiPrec, &
                           rB,tag, &
                           mesh%decomp%mpiComm, &
                           mesh%decomp%requests(msgCount),iError)

          endif

        enddo
      enddo
    enddo

    mesh%decomp%msgCount = msgCount

  endsubroutine MPIAnisoMortarExchangeAsync_MappedScalar3D_t