GPU-resident mortar message posting for vector data; messages are posted on device memory (GPU-aware MPI), one per variable and physical direction.
| Type | Intent | Optional | Attributes | Name | ||
|---|---|---|---|---|---|---|
| class(MappedVector2D), | intent(inout) | :: | this | |||
| type(Mesh2D), | intent(inout) | :: | mesh |
subroutine MPIMortarExchangeAsync_MappedVector2D(this,mesh)
!! GPU-resident mortar message posting for vector data; messages are posted on
!! device memory (GPU-aware MPI), one per variable and physical direction.
implicit none
class(MappedVector2D),intent(inout) :: this
type(Mesh2D),intent(inout) :: mesh
! Local
integer :: m,k,ivar,idir
integer :: eB,sB,rB,eS,sS,rS
integer :: globalSideId,tag
integer :: offset
integer :: iError
integer :: msgCount
real(prec),pointer :: boundary(:,:,:,:,:)
real(prec),pointer :: mortarBuff(:,:,:,:,:)
msgCount = 0
offset = mesh%decomp%offsetElem(mesh%decomp%rankId+1)
call c_f_pointer(this%boundary_gpu,boundary,[this%interp%N+1,4,this%nelem,this%nvar,2])
call c_f_pointer(this%mortarBuff_gpu,mortarBuff, &
[this%interp%N+1,4,mesh%nMortars,this%nvar,2])
do idir = 1,2
do ivar = 1,this%nvar
do m = 1,mesh%nMortars
eB = mesh%mortarInfo(1,m)
sB = mesh%mortarInfo(2,m)
rB = mesh%decomp%elemToRank(eB)
do k = 1,2
eS = mesh%mortarInfo(2*k+1,m)
sS = mesh%mortarInfo(2*k+2,m)/10
rS = mesh%decomp%elemToRank(eS)
globalSideId = mesh%mortarInfo(6+k,m)
tag = globalSideId+mesh%nUniqueSides*(ivar-1+this%nvar*(idir-1))
if(rB == mesh%decomp%rankId .and. rS /= mesh%decomp%rankId) then
msgCount = msgCount+1
call MPI_IRECV(mortarBuff(:,2+k,m,ivar,idir), &
(this%interp%N+1), &
mesh%decomp%mpiPrec, &
rS,tag, &
mesh%decomp%mpiComm, &
mesh%decomp%requests(msgCount),iError)
msgCount = msgCount+1
call MPI_ISEND(boundary(:,sB,eB-offset,ivar,idir), &
(this%interp%N+1), &
mesh%decomp%mpiPrec, &
rS,tag, &
mesh%decomp%mpiComm, &
mesh%decomp%requests(msgCount),iError)
elseif(rS == mesh%decomp%rankId .and. rB /= mesh%decomp%rankId) then
msgCount = msgCount+1
call MPI_IRECV(mortarBuff(:,k,m,ivar,idir), &
(this%interp%N+1), &
mesh%decomp%mpiPrec, &
rB,tag, &
mesh%decomp%mpiComm, &
mesh%decomp%requests(msgCount),iError)
msgCount = msgCount+1
call MPI_ISEND(boundary(:,sS,eS-offset,ivar,idir), &
(this%interp%N+1), &
mesh%decomp%mpiPrec, &
rB,tag, &
mesh%decomp%mpiComm, &
mesh%decomp%requests(msgCount),iError)
endif
enddo
enddo
enddo
enddo
mesh%decomp%msgCount = msgCount
endsubroutine MPIMortarExchangeAsync_MappedVector2D